migrate all tabs to be plugins

Netdisco/lib/App/Netdisco/Web/Plugin/Device/Addresses.pm

@@ -0,0 +1,26 @@
+package App::Netdisco::Web::Plugin::Device::Addresses;
+
+use Dancer ':syntax';
+use Dancer::Plugin::Ajax;
+use Dancer::Plugin::DBIC;
+
+use App::Netdisco::Web::Plugin;
+
+register_device_tab({ id => 'addresses', label => 'Addresses' });
+
+# device interface addresses
+ajax '/ajax/content/device/addresses' => sub {
+    my $ip = param('q');
+    return unless $ip;
+
+    my $set = schema('netdisco')->resultset('DeviceIp')
+                ->search({ip => $ip}, {order_by => 'alias'});
+    return unless $set->count;
+
+    content_type('text/html');
+    template 'ajax/device/addresses.tt', {
+      results => $set,
+    }, { layout => undef };
+};
+
+true;

Netdisco/lib/App/Netdisco/Web/Plugin/Device/Details.pm

@@ -0,0 +1,26 @@
+package App::Netdisco::Web::Plugin::Device::Details;
+
+use Dancer ':syntax';
+use Dancer::Plugin::Ajax;
+use Dancer::Plugin::DBIC;
+
+use App::Netdisco::Web::Plugin;
+
+register_device_tab({ id => 'details', label => 'Details' });
+
+# device details table
+ajax '/ajax/content/device/details' => sub {
+    my $ip = param('q');
+    return unless $ip;
+
+    my $device = schema('netdisco')->resultset('Device')
+                   ->with_times()->find($ip);
+    return unless $device;
+
+    content_type('text/html');
+    template 'ajax/device/details.tt', {
+      d => $device,
+    }, { layout => undef };
+};
+
+true;

Netdisco/lib/App/Netdisco/Web/Plugin/Device/Modules.pm

@@ -0,0 +1,14 @@
+package App::Netdisco::Web::Plugin::Device::Modules;
+
+use Dancer ':syntax';
+use Dancer::Plugin::Ajax;
+
+use App::Netdisco::Web::Plugin;
+
+register_device_tab({ id => 'modules', label => 'Modules' });
+
+ajax '/ajax/content/device/:thing' => sub {
+    return "<p>Hello, this is where the ". param('thing') ." content goes.</p>";
+};
+
+true;

Netdisco/lib/App/Netdisco/Web/Plugin/Device/Neighbors.pm

@@ -0,0 +1,96 @@
+package App::Netdisco::Web::Plugin::Device::Neighbors;
+
+use Dancer ':syntax';
+use Dancer::Plugin::Ajax;
+use Dancer::Plugin::DBIC;
+
+use App::Netdisco::Web::Plugin;
+
+register_device_tab({ id => 'netmap', label => 'Neighbors' });
+
+ajax '/ajax/content/device/netmap' => sub {
+    content_type('text/html');
+    template 'ajax/device/netmap.tt', {}, { layout => undef };
+};
+
+sub _get_name {
+    my $ip = shift;
+    my $domain = quotemeta( setting('domain_suffix') || '' );
+
+    (my $dns = (var('devices')->{$ip} || '')) =~ s/$domain$//;
+    return ($dns || $ip);
+}
+
+sub _add_children {
+    my ($ptr, $childs) = @_;
+    my @legit = ();
+
+    foreach my $c (@$childs) {
+        next if exists var('seen')->{$c};
+        var('seen')->{$c}++;
+        push @legit, $c;
+        push @{$ptr}, { name => _get_name($c), ip => $c };
+    }
+
+    for (my $i = 0; $i < @legit; $i++) {
+        $ptr->[$i]->{children} = [];
+        _add_children($ptr->[$i]->{children}, var('links')->{$legit[$i]});
+    }
+}
+
+# d3 seems not to use proper ajax semantics, so get instead of ajax
+get '/ajax/data/device/netmap' => sub {
+    my $start = param('q');
+    return unless $start;
+
+    my @devices = schema('netdisco')->resultset('Device')->search({}, {
+      result_class => 'DBIx::Class::ResultClass::HashRefInflator',
+      columns => ['ip', 'dns'],
+    })->all;
+    var(devices => { map { $_->{ip} => $_->{dns} } @devices });
+
+    var(links => {});
+    my $rs = schema('netdisco')->resultset('Virtual::DeviceLinks')->search({}, {
+      result_class => 'DBIx::Class::ResultClass::HashRefInflator',
+    });
+
+    while (my $l = $rs->next) {
+        var('links')->{ $l->{left_ip} } ||= [];
+        push @{ var('links')->{ $l->{left_ip} } }, $l->{right_ip};
+    }
+
+    my %tree = (
+        ip => $start,
+        name => _get_name($start),
+        children => [],
+    );
+
+    var(seen => {$start => 1});
+    _add_children($tree{children}, var('links')->{$start});
+
+    content_type('application/json');
+    return to_json(\%tree);
+};
+
+ajax '/ajax/data/device/alldevicelinks' => sub {
+    my @devices = schema('netdisco')->resultset('Device')->search({}, {
+      result_class => 'DBIx::Class::ResultClass::HashRefInflator',
+      columns => ['ip', 'dns'],
+    })->all;
+    var(devices => { map { $_->{ip} => $_->{dns} } @devices });
+
+    my $rs = schema('netdisco')->resultset('Virtual::DeviceLinks')->search({}, {
+      result_class => 'DBIx::Class::ResultClass::HashRefInflator',
+    });
+
+    my %tree = ();
+    while (my $l = $rs->next) {
+        push @{ $tree{ _get_name($l->{left_ip} )} },
+          _get_name($l->{right_ip});
+    }
+
+    content_type('application/json');
+    return to_json(\%tree);
+};
+
+true;

Netdisco/lib/App/Netdisco/Web/Plugin/Device/Ports.pm

@@ -0,0 +1,85 @@
+package App::Netdisco::Web::Plugin::Device::Ports;
+
+use Dancer ':syntax';
+use Dancer::Plugin::Ajax;
+use Dancer::Plugin::DBIC;
+
+use App::Netdisco::Util::Web (); # for sort_port
+
+use App::Netdisco::Web::Plugin;
+
+register_device_tab({ id => 'ports', label => 'Ports' });
+
+# device ports with a description (er, name) matching
+ajax '/ajax/content/device/ports' => sub {
+    my $ip = param('q');
+    return unless $ip;
+
+    my $set = schema('netdisco')->resultset('DevicePort')
+                ->search({'me.ip' => $ip});
+
+    # refine by ports if requested
+    my $q = param('f');
+    if ($q) {
+        if ($q =~ m/^\d+$/) {
+            $set = $set->search({
+              -or => {
+                'me.vlan' => $q,
+                'port_vlans_tagged.vlan' => $q,
+              },
+            }, { join => 'port_vlans_tagged' });
+            return unless $set->count;
+        }
+        else {
+            $q =~ s/\*/%/g if index($q, '*') >= 0;
+            $q =~ s/\?/_/g if index($q, '?') >= 0;
+            $q = { '-ilike' => $q };
+
+            if ($set->search({'me.port' => $q})->count) {
+                $set = $set->search({'me.port' => $q});
+            }
+            else {
+                $set = $set->search({'me.name' => $q});
+                return unless $set->count;
+            }
+        }
+    }
+
+    # filter for free ports if asked
+    my $free_filter = (param('free') ? 'only_free_ports' : 'with_is_free');
+    $set = $set->$free_filter({
+      age_num => (param('age_num') || 3),
+      age_unit => (param('age_unit') || 'months')
+    });
+
+    # make sure query asks for formatted timestamps when needed
+    $set = $set->with_times if param('c_lastchange');
+
+    # get number of vlans on the port to control whether to list them or not
+    $set = $set->with_vlan_count if param('c_vmember');
+
+    # what kind of nodes are we interested in?
+    my $nodes_name = (param('n_archived') ? 'nodes' : 'active_nodes');
+    $nodes_name .= '_with_age' if param('c_nodes') and param('n_age');
+
+    # retrieve active/all connected nodes, if asked for
+    $set = $set->search_rs({}, { prefetch => [{$nodes_name => 'ips'}] })
+      if param('c_nodes');
+
+    # retrieve neighbor devices, if asked for
+    $set = $set->search_rs({}, { prefetch => [{neighbor_alias => 'device'}] })
+      if param('c_neighbors');
+
+    # sort ports (empty set would be a 'no records' msg)
+    my $results = [ sort { &App::Netdisco::Util::Web::sort_port($a->port, $b->port) } $set->all ];
+    return unless scalar @$results;
+
+    content_type('text/html');
+    template 'ajax/device/ports.tt', {
+      results => $results,
+      nodes => $nodes_name,
+      device => $ip,
+    }, { layout => undef };
+};
+
+true;