move remaining interactive actions to be plugins

lib/App/Netdisco/Worker/Plugin/PortControl.pm

@@ -0,0 +1,69 @@
+package App::Netdisco::Worker::Plugin::PortControl;
+
+use Dancer ':syntax';
+use App::Netdisco::Worker::Plugin;
+use aliased 'App::Netdisco::Worker::Status';
+
+use App::Netdisco::Transport::SNMP;
+use App::Netdisco::Util::Port ':all';
+
+register_worker({ stage => 'check' }, sub {
+  my ($job, $workerconf) = @_;
+  my ($device, $pn) = map {$job->$_} qw/device port/;
+  return Status->error('Missing device (-d).') if !defined $device;
+  return Status->error('Missing port (-p).') if !defined $pn;
+  return Status->error('Missing status (-e).') if !defined $job->subaction;
+
+  my $port = get_port($device, $pn)
+    or return Status->error("Unknown port name [$pn] on device $device");
+
+  my $port_reconfig_check = port_reconfig_check($port);
+  return Status->error("Cannot alter port: $port_reconfig_check")
+    if $port_reconfig_check;
+
+  # need to remove "-other" which appears for power/portcontrol
+  (my $sa = $job->subaction) =~ s/-\w+//;
+  $job->subaction($sa);
+
+  if ($sa eq 'bounce') {
+    $job->subaction('down');
+    my $status = _action($job, $port);
+    return $status if $status->not_ok;
+    $job->subaction('up');
+  }
+
+  return _action($job, $port);
+});
+
+sub _action {
+  my ($job, $port) = @_;
+  my ($device, $pn, $data) = map {$job->$_} qw/device port subaction/;
+
+  # snmp connect using rw community
+  my $snmp = App::Netdisco::Transport::SNMP->writer_for($device)
+    or return Status->defer("failed to connect to $device to update up_admin");
+
+  my $iid = get_iid($snmp, $port)
+    or return Status->error("Failed to get port ID for [$pn] from $device");
+
+  my $rv = $snmp->set_i_up_admin($data, $iid);
+
+  if (!defined $rv) {
+      return Status->error(sprintf 'Failed to set [%s] up_admin to [%s] on $device: %s',
+                    $pn, $data, ($snmp->error || ''));
+  }
+
+  # confirm the set happened
+  $snmp->clear_cache;
+  my $state = ($snmp->i_up_admin($iid) || '');
+  if (ref {} ne ref $state or $state->{$iid} ne $data) {
+      return Status->error("Verify of [$pn] up_admin failed on $device");
+  }
+
+  # update netdisco DB
+  $port->update({up_admin => $data});
+
+  return Status->done("Updated [$pn] up_admin on [$device] to [$data]");
+}
+
+true;