Add Nodes with multiple IP addresses report

Netdisco/Changes

@@ -2,6 +2,7 @@
 
   [NEW FEATURES]
   * Add Device PoE status report
+  * Add Nodes with multiple IP addresses report
 
   [ENHANCEMENTS]
 

Netdisco/lib/App/Netdisco/DB/ResultSet/Node.pm

@@ -125,4 +125,68 @@ sub delete {
   }
 }
 
+=head2 with_multi_ips_as_hashref
+
+This is a modifier for C<search()> which returns a list of hash references
+for nodes within the search criteria with multiple IP addresses.  Each hash
+reference contains the keys:
+
+=over 4
+
+=item mac
+
+Node MAC address.
+
+=item switch
+
+IP address of the device where the node is attached.
+
+=item port
+
+Port on the device where the node is attached.
+
+=item dns
+
+DNS name of the device where the node is attached.
+
+=item name
+
+C<sysName> of the device where the node is attached.
+
+=item ip_count
+
+Count of IP addresses associated with the node.
+
+=item vendor
+
+Vendor string based upon the node OUI.
+
+=back
+
+=cut
+
+sub with_multi_ips_as_hashref {
+  my ( $rs, $cond, $attrs ) = @_;
+
+  my @return = $rs->search(
+    {},
+    { result_class => 'DBIx::Class::ResultClass::HashRefInflator',
+      select       => [ 'mac', 'switch', 'port' ],
+      join         => [qw/device ips oui/],
+      '+columns'   => [
+        { 'dns'      => 'device.dns' },
+        { 'name'     => 'device.name' },
+        { 'ip_count' => { count => 'ips.ip' } },
+        { 'vendor'   => 'oui.company' }
+      ],
+      group_by =>
+        [qw/ me.mac me.switch me.port device.dns device.name oui.company/],
+      having => \[ 'count(ips.ip) > ?', [ count => 1 ] ],
+      order_by => { -desc => [qw/count/] },
+    }
+  )->all;
+
+  return \@return;
+}
+
 1;

Netdisco/lib/App/Netdisco/Web/Plugin/Report/NodeMultiIPs.pm

@@ -0,0 +1,35 @@
+package App::Netdisco::Web::Plugin::Report::NodeMultiIPs;
+
+use Dancer ':syntax';
+use Dancer::Plugin::DBIC;
+use Dancer::Plugin::Auth::Extensible;
+
+use App::Netdisco::Web::Plugin;
+
+register_report(
+    {   category     => 'Node',
+        tag          => 'nodemultiips',
+        label        => 'Nodes with multiple active IP addresses',
+        provides_csv => 1,
+    }
+);
+
+get '/ajax/content/report/nodemultiips' => require_login sub {
+    my $results = schema('netdisco')->resultset('Node')
+        ->with_multi_ips_as_hashref;
+
+    return unless scalar $results;
+
+    if ( request->is_ajax ) {
+        template 'ajax/report/nodemultiips.tt', { results => $results, },
+            { layout => undef };
+    }
+    else {
+        header( 'Content-Type' => 'text/comma-separated-values' );
+        template 'ajax/report/nodemultiips_csv.tt',
+            { results => $results, },
+            { layout  => undef };
+    }
+};
+
+1;

Netdisco/share/config.yml

@@ -40,6 +40,7 @@ web_plugins:
   - Report::DeviceByLocation
   - Report::DevicePoeStatus
   - Report::DuplexMismatch
+  - Report::NodeMultiIPs
   - Report::SsidInventory
   - Report::VlanInventory
   - AdminTask::JobQueue

Netdisco/share/views/ajax/report/nodemultiips.tt

@@ -0,0 +1,24 @@
+[% USE Number.Format %]
+<table class="table table-bordered table-condensed table-striped nd_floatinghead">
+  <thead>
+    <tr>
+      <th class="nd_center-cell">MAC</th>
+      <th class="nd_center-cell">Vendor</th>
+      <th class="nd_center-cell">Location</th>
+      <th class="nd_center-cell">IPs</th>
+    </tr>
+  </thead>
+  </tbody>
+    [% FOREACH row IN results %]
+    <tr>
+      <td class="nd_center-cell"><a href="[% search_node %]&q=[% row.mac.upper | uri %]">
+            [% row.mac.upper | html_entity %]</a>
+      <td class="nd_center-cell">[% row.vendor | html_entity %]</td>
+      <td class="nd_center-cell"><a href="[% device_ports %]&q=[% row.dns || row.switch | uri %]&f=[% row.port | uri %]&c_nodes=on">
+               [% row.dns || row.name || row.switch | html_entity %] ([% row.port | html_entity %])</a></td>
+      <td class="nd_center-cell">[% row.ip_count | format_number %]</td>
+    </tr>
+    [% END %]
+  </tbody>
+</table>
+

Netdisco/share/views/ajax/report/nodemultiips_csv.tt

@@ -0,0 +1,13 @@
+[% USE CSV -%]
+[% CSV.dump([ 'MAC' 'Vendor' 'Switch' 'Port' 'IPs' ]) %]
+
+[% FOREACH row IN results %]
+  [% mylist = [] %]
+  [% mylist.push(row.mac.upper) %]
+  [% mylist.push(row.vendor) %]
+  [% mylist.push(row.dns || row.name || row.switch) %]
+  [% mylist.push(row.port) %]
+  [% mylist.push(row.ip_count) %]
+  [% CSV.dump(mylist) %]
+
+[% END %]