[#70] SSID Search (port)

Netdisco/lib/App/Netdisco/DB/ResultSet/DevicePortSsid.pm

@@ -0,0 +1,48 @@
+package App::Netdisco::DB::ResultSet::DevicePortSsid;
+use base 'App::Netdisco::DB::ResultSet';
+
+use strict;
+use warnings FATAL => 'all';
+
+__PACKAGE__->load_components(
+    qw/
+        +App::Netdisco::DB::ExplicitLocking
+        /
+);
+
+=head1 ADDITIONAL METHODS
+
+=head2 get_ssids
+
+Returns a sorted list of SSIDs with the following columns only:
+
+=over 4
+
+=item ssid
+
+=item broadcast
+
+=item count
+
+=back
+
+Where C<count> is the number of instances of the SSID in the Netdisco
+database.
+
+=cut
+
+sub get_ssids {
+    my $rs = shift;
+
+    return $rs->search(
+        {},
+        {   select => [ 'ssid', 'broadcast', { count => 'ssid' } ],
+            as       => [qw/ ssid broadcast count /],
+            group_by => [qw/ ssid broadcast /],
+            order_by => { -desc => [qw/count/] },
+        }
+        )
+
+}
+
+1;

Netdisco/lib/App/Netdisco/Web/Plugin/Report/PortSsid.pm

@@ -0,0 +1,70 @@
+package App::Netdisco::Web::Plugin::Report::PortSsid;
+
+use Dancer ':syntax';
+use Dancer::Plugin::DBIC;
+use Dancer::Plugin::Auth::Extensible;
+
+use App::Netdisco::Web::Plugin;
+
+register_report(
+    {   category     => 'Port',
+        tag          => 'portssid',
+        label        => 'Port SSID Inventory',
+        provides_csv => 1,
+    }
+);
+
+hook 'before_template' => sub {
+    my $tokens = shift;
+
+    return
+        unless (
+        request->path eq uri_for('/report/portssid')->path
+        or index(
+            request->path, uri_for('/ajax/content/report/portssid')->path
+        ) == 0
+        );
+
+    # used in the search sidebar template to set selected items
+    foreach my $opt (qw/ssid/) {
+        my $p = (
+            ref [] eq ref param($opt)
+            ? param($opt)
+            : ( param($opt) ? [ param($opt) ] : [] )
+        );
+        $tokens->{"${opt}_lkp"} = { map { $_ => 1 } @$p };
+    }
+};
+
+get '/ajax/content/report/portssid' => require_login sub {
+
+    my $ssid = param('ssid');
+
+    my $rs = schema('netdisco')->resultset('DevicePortSsid');
+
+    if ( defined $ssid ) {
+
+        $rs
+            = $rs->search( { ssid => $ssid } )
+            ->prefetch( [qw/ device port /] )
+            ->order_by( [qw/ port.ip port.port /] )->hri;
+    }
+    else {
+        $rs = $rs->get_ssids->hri;
+
+    }
+
+    return unless $rs->has_rows;
+
+    if ( request->is_ajax ) {
+        template 'ajax/report/portssid.tt', { results => $rs, },
+            { layout => undef };
+    }
+    else {
+        header( 'Content-Type' => 'text/comma-separated-values' );
+        template 'ajax/report/portssid_csv.tt', { results => $rs, },
+            { layout => undef };
+    }
+};
+
+1;

Netdisco/lib/App/Netdisco/Web/Report.pm

@@ -14,6 +14,8 @@ get '/report/*' => require_login sub {
         ];
     my $class_list = [ schema('netdisco')->resultset('DeviceModule')
             ->get_distinct_col('class') ];
+    my $ssid_list = [ schema('netdisco')->resultset('DevicePortSsid')
+            ->get_distinct_col('ssid') ];
 
     # trick the ajax into working as if this were a tabbed page
     params->{tab} = $tag;
@@ -24,6 +26,7 @@ get '/report/*' => require_login sub {
         report      => setting('_reports')->{$tag},
         domain_list => $domain_list,
         class_list  => $class_list,
+        ssid_list   => $ssid_list,
         };
 };