dc1f76c1aa
* fix anomalous name * add gather worker * fix encoding of binary storage * store results back to job * now parsing mbis report to translate * fix the broken report parser * rename gather to snapshot * implement walk code copied from SNMP::Info * can now bulkwalk and parse mibs report and store resolved walk in cache * add func/glob aliasing broken * better aliasing * implement aliasing from globals and funcs * fix regexp for matching netdisco-mibs report * fake cache entry for all ND2 methods called, add comments * also save to logs/snapshots/IP * add doc for netdisco-do * add is_pseudo column to device table * support for loading cache for pseudo devices * check for hrSystemUptime as well as sysUpTime for snmp connect * display pseudo devices with yellow pill for name * color all cells for layers for pseudo * no need to b64 encode binary data in scalars as we b64 whole thing after * tweaked uptime check * store snapshot to database instead of Job * expose snapshots in device details tab * small ux improvements on snap download * fixes for errors in subnet mask searching * hide snapshot management for pseudo devices * update to use new netdisco-mibs object cache * update for new format oids file * start of work on loading walk into db for browsing * store values and meta * add auto increment col and oid index to browser * start web plugin for browser * add virtual search for oid children * have all oid in separte table (60 seconds load on my laptop) * rename table and add relation * store oid as int array * fix sql for children * make jstree start working * working very slow tree expand * fix to work when first displaying tree * store both oid and oid_parts * simplify SQL to speed up (more complicated perl) * fix sql bug, add better index, prettify tree * render the snmp node detail * add node template, make scrollable, pretty print data values (insecure) * store munge hint * some dubious code to munge the data * make sure to filter by IP on device_browser * make safer the rendering of value data (but need to come back to key ordering) * fix sorting on object values * limit the opening of child nodes to keep response good and unclutter * factor out the munge and make safer * reject unknown mungers * show the munger and option (not working) to change * additional js for munge select * complete custom munge * change so that saving to database is only at CLI and on request * hide snmp tab if no browser rows in the db * add helpful message when no browser rows for the device * stub handler for search and add recurse control * working search * minor ui fixes * implement typeahead for leaf search * limit rows in typeahead * make sure device_browser is visited in delete and renumber * add requirements for this branch * update manifest * make sure node search and typeahead are restricted to current device only
75 lines
2.0 KiB
Perl
75 lines
2.0 KiB
Perl
package App::Netdisco::Worker::Plugin::Arpnip::Subnets;
|
|
|
|
use Dancer ':syntax';
|
|
use App::Netdisco::Worker::Plugin;
|
|
use aliased 'App::Netdisco::Worker::Status';
|
|
|
|
use App::Netdisco::Transport::SNMP ();
|
|
use App::Netdisco::Util::Permission 'check_acl_no';
|
|
use Dancer::Plugin::DBIC 'schema';
|
|
use NetAddr::IP::Lite ':lower';
|
|
use Time::HiRes 'gettimeofday';
|
|
|
|
register_worker({ phase => 'main', driver => 'snmp' }, sub {
|
|
my ($job, $workerconf) = @_;
|
|
|
|
my $device = $job->device;
|
|
my $snmp = App::Netdisco::Transport::SNMP->reader_for($device)
|
|
or return Status->defer("arpnip failed: could not SNMP connect to $device");
|
|
|
|
# get directly connected networks
|
|
my @subnets = gather_subnets($device);
|
|
# TODO: IPv6 subnets
|
|
|
|
my $now = 'to_timestamp('. (join '.', gettimeofday) .')';
|
|
store_subnet($_, $now) for @subnets;
|
|
|
|
return Status->info(sprintf ' [%s] arpnip - processed %s Subnet entries',
|
|
$device->ip, scalar @subnets);
|
|
});
|
|
|
|
# gathers device subnets
|
|
sub gather_subnets {
|
|
my $device = shift;
|
|
my @subnets = ();
|
|
|
|
my $snmp = App::Netdisco::Transport::SNMP->reader_for($device)
|
|
or return (); # already checked!
|
|
|
|
my $ip_netmask = $snmp->ip_netmask;
|
|
foreach my $entry (keys %$ip_netmask) {
|
|
my $ip = NetAddr::IP::Lite->new($entry) or next;
|
|
my $addr = $ip->addr;
|
|
|
|
next if $addr eq '0.0.0.0';
|
|
next if check_acl_no($ip, 'group:__LOCAL_ADDRESSES__');
|
|
next if setting('ignore_private_nets') and $ip->is_rfc1918;
|
|
|
|
my $netmask = $ip_netmask->{$addr} || $ip->bits();
|
|
next if $netmask eq '255.255.255.255' or $netmask eq '0.0.0.0';
|
|
|
|
my $cidr = NetAddr::IP::Lite->new($addr, $netmask)->network->cidr;
|
|
|
|
debug sprintf ' [%s] arpnip - found subnet %s', $device->ip, $cidr;
|
|
push @subnets, $cidr;
|
|
}
|
|
|
|
return @subnets;
|
|
}
|
|
|
|
# update subnets with new networks
|
|
sub store_subnet {
|
|
my ($subnet, $now) = @_;
|
|
|
|
schema('netdisco')->txn_do(sub {
|
|
schema('netdisco')->resultset('Subnet')->update_or_create(
|
|
{
|
|
net => $subnet,
|
|
last_discover => \$now,
|
|
},
|
|
{ for => 'update' });
|
|
});
|
|
}
|
|
|
|
true;
|