dc1f76c1aa
* fix anomalous name * add gather worker * fix encoding of binary storage * store results back to job * now parsing mbis report to translate * fix the broken report parser * rename gather to snapshot * implement walk code copied from SNMP::Info * can now bulkwalk and parse mibs report and store resolved walk in cache * add func/glob aliasing broken * better aliasing * implement aliasing from globals and funcs * fix regexp for matching netdisco-mibs report * fake cache entry for all ND2 methods called, add comments * also save to logs/snapshots/IP * add doc for netdisco-do * add is_pseudo column to device table * support for loading cache for pseudo devices * check for hrSystemUptime as well as sysUpTime for snmp connect * display pseudo devices with yellow pill for name * color all cells for layers for pseudo * no need to b64 encode binary data in scalars as we b64 whole thing after * tweaked uptime check * store snapshot to database instead of Job * expose snapshots in device details tab * small ux improvements on snap download * fixes for errors in subnet mask searching * hide snapshot management for pseudo devices * update to use new netdisco-mibs object cache * update for new format oids file * start of work on loading walk into db for browsing * store values and meta * add auto increment col and oid index to browser * start web plugin for browser * add virtual search for oid children * have all oid in separte table (60 seconds load on my laptop) * rename table and add relation * store oid as int array * fix sql for children * make jstree start working * working very slow tree expand * fix to work when first displaying tree * store both oid and oid_parts * simplify SQL to speed up (more complicated perl) * fix sql bug, add better index, prettify tree * render the snmp node detail * add node template, make scrollable, pretty print data values (insecure) * store munge hint * some dubious code to munge the data * make sure to filter by IP on device_browser * make safer the rendering of value data (but need to come back to key ordering) * fix sorting on object values * limit the opening of child nodes to keep response good and unclutter * factor out the munge and make safer * reject unknown mungers * show the munger and option (not working) to change * additional js for munge select * complete custom munge * change so that saving to database is only at CLI and on request * hide snmp tab if no browser rows in the db * add helpful message when no browser rows for the device * stub handler for search and add recurse control * working search * minor ui fixes * implement typeahead for leaf search * limit rows in typeahead * make sure device_browser is visited in delete and renumber * add requirements for this branch * update manifest * make sure node search and typeahead are restricted to current device only
106 lines
3.2 KiB
Perl
106 lines
3.2 KiB
Perl
package App::Netdisco::Web::AdminTask;
|
|
|
|
use Dancer ':syntax';
|
|
use Dancer::Plugin::Ajax;
|
|
use Dancer::Plugin::DBIC;
|
|
use Dancer::Plugin::Auth::Extensible;
|
|
|
|
use NetAddr::IP qw/:rfc3021 :lower/;
|
|
use App::Netdisco::JobQueue 'jq_insert';
|
|
use App::Netdisco::Util::Device 'delete_device';
|
|
|
|
sub add_job {
|
|
my ($action, $device, $subaction) = @_;
|
|
|
|
my $net = NetAddr::IP->new($device);
|
|
return if
|
|
($device and (!$net or $net->num == 0 or $net->addr eq '0.0.0.0'));
|
|
|
|
my @hostlist = $device ? ($net->hostenum) : (undef);
|
|
|
|
jq_insert([map {{
|
|
($_ ? (device => $_->addr) : ()),
|
|
action => $action,
|
|
($subaction ? (subaction => $subaction) : ()),
|
|
username => session('logged_in_user'),
|
|
userip => request->remote_address,
|
|
}} @hostlist]);
|
|
|
|
true;
|
|
}
|
|
|
|
foreach my $action (@{ setting('job_prio')->{high} },
|
|
@{ setting('job_prio')->{normal} }) {
|
|
|
|
next if $action and $action =~ m/^hook::/; # skip hooks
|
|
|
|
ajax "/ajax/control/admin/$action" => require_role admin => sub {
|
|
add_job($action, param('device'), param('extra'))
|
|
or send_error('Bad device', 400);
|
|
};
|
|
|
|
post "/admin/$action" => require_role admin => sub {
|
|
add_job($action, param('device'), param('extra'))
|
|
? redirect uri_for('/admin/jobqueue')->path
|
|
: redirect uri_for('/')->path;
|
|
};
|
|
}
|
|
|
|
ajax qr{/ajax/control/admin/(?:\w+/)?delete} => require_role setting('defanged_admin') => sub {
|
|
send_error('Missing device', 400) unless param('device');
|
|
|
|
my $device = NetAddr::IP->new(param('device'));
|
|
send_error('Bad device', 400)
|
|
if ! $device or $device->addr eq '0.0.0.0';
|
|
|
|
return delete_device(
|
|
$device->addr, param('archive'), param('log'),
|
|
);
|
|
};
|
|
|
|
ajax "/ajax/control/admin/snapshot_req" => require_role admin => sub {
|
|
my $device = NetAddr::IP->new(param('device'));
|
|
send_error('Bad device', 400)
|
|
if ! $device or $device->addr eq '0.0.0.0';
|
|
|
|
add_job('snapshot', $device->addr) or send_error('Bad device', 400);
|
|
};
|
|
|
|
get "/ajax/content/admin/snapshot_get" => require_role admin => sub {
|
|
my $device = NetAddr::IP->new(param('device'));
|
|
send_error('Bad device', 400)
|
|
if ! $device or $device->addr eq '0.0.0.0';
|
|
|
|
my $content = schema('netdisco')->resultset('DeviceSnapshot')->find($device->addr)->cache;
|
|
send_file( \$content, content_type => 'text/plain', filename => ($device->addr .'-snapshot.txt') );
|
|
};
|
|
|
|
ajax "/ajax/control/admin/snapshot_del" => require_role setting('defanged_admin') => sub {
|
|
my $device = NetAddr::IP->new(param('device'));
|
|
send_error('Bad device', 400)
|
|
if ! $device or $device->addr eq '0.0.0.0';
|
|
|
|
schema('netdisco')->resultset('DeviceSnapshot')->find($device->addr)->delete;
|
|
};
|
|
|
|
get '/admin/*' => require_role admin => sub {
|
|
my ($tag) = splat;
|
|
|
|
if (exists setting('_admin_tasks')->{ $tag }) {
|
|
# trick the ajax into working as if this were a tabbed page
|
|
params->{tab} = $tag;
|
|
|
|
var(nav => 'admin');
|
|
template 'admintask', {
|
|
task => setting('_admin_tasks')->{ $tag },
|
|
}, { layout => 'main' };
|
|
}
|
|
else {
|
|
var('notfound' => true);
|
|
status 'not_found';
|
|
template 'index', {}, { layout => 'main' };
|
|
}
|
|
};
|
|
|
|
true;
|