dc1f76c1aa
* fix anomalous name * add gather worker * fix encoding of binary storage * store results back to job * now parsing mbis report to translate * fix the broken report parser * rename gather to snapshot * implement walk code copied from SNMP::Info * can now bulkwalk and parse mibs report and store resolved walk in cache * add func/glob aliasing broken * better aliasing * implement aliasing from globals and funcs * fix regexp for matching netdisco-mibs report * fake cache entry for all ND2 methods called, add comments * also save to logs/snapshots/IP * add doc for netdisco-do * add is_pseudo column to device table * support for loading cache for pseudo devices * check for hrSystemUptime as well as sysUpTime for snmp connect * display pseudo devices with yellow pill for name * color all cells for layers for pseudo * no need to b64 encode binary data in scalars as we b64 whole thing after * tweaked uptime check * store snapshot to database instead of Job * expose snapshots in device details tab * small ux improvements on snap download * fixes for errors in subnet mask searching * hide snapshot management for pseudo devices * update to use new netdisco-mibs object cache * update for new format oids file * start of work on loading walk into db for browsing * store values and meta * add auto increment col and oid index to browser * start web plugin for browser * add virtual search for oid children * have all oid in separte table (60 seconds load on my laptop) * rename table and add relation * store oid as int array * fix sql for children * make jstree start working * working very slow tree expand * fix to work when first displaying tree * store both oid and oid_parts * simplify SQL to speed up (more complicated perl) * fix sql bug, add better index, prettify tree * render the snmp node detail * add node template, make scrollable, pretty print data values (insecure) * store munge hint * some dubious code to munge the data * make sure to filter by IP on device_browser * make safer the rendering of value data (but need to come back to key ordering) * fix sorting on object values * limit the opening of child nodes to keep response good and unclutter * factor out the munge and make safer * reject unknown mungers * show the munger and option (not working) to change * additional js for munge select * complete custom munge * change so that saving to database is only at CLI and on request * hide snmp tab if no browser rows in the db * add helpful message when no browser rows for the device * stub handler for search and add recurse control * working search * minor ui fixes * implement typeahead for leaf search * limit rows in typeahead * make sure device_browser is visited in delete and renumber * add requirements for this branch * update manifest * make sure node search and typeahead are restricted to current device only
93 lines
2.9 KiB
Perl
93 lines
2.9 KiB
Perl
package App::Netdisco::Web::Device;
|
|
|
|
use Dancer ':syntax';
|
|
use Dancer::Plugin::Ajax;
|
|
use Dancer::Plugin::DBIC;
|
|
use Dancer::Plugin::Auth::Extensible;
|
|
|
|
use URI ();
|
|
use URL::Encode 'url_params_mixed';
|
|
use App::Netdisco::Util::Device 'match_to_setting';
|
|
|
|
# build view settings for port connected nodes and devices
|
|
set('connected_properties' => [
|
|
sort { $a->{idx} <=> $b->{idx} }
|
|
map {{ name => $_, %{ setting('sidebar_defaults')->{'device_ports'}->{$_} } }}
|
|
grep { $_ =~ m/^n_/ } keys %{ setting('sidebar_defaults')->{'device_ports'} }
|
|
]);
|
|
|
|
hook 'before_template' => sub {
|
|
my $tokens = shift;
|
|
|
|
# allow checking of discoverability of remote connected device
|
|
$tokens->{has_snmp} = sub { not match_to_setting(shift, 'discover_no_type') };
|
|
|
|
my $defaults = var('sidebar_defaults')->{'device_ports'}
|
|
or return;
|
|
|
|
# override ports form defaults with cookie settings
|
|
# always do this so that embedded links to device ports page have user prefs
|
|
if (param('reset')) {
|
|
cookie('nd_ports-form' => '', expires => '-1 day');
|
|
}
|
|
elsif (my $cookie = cookie('nd_ports-form')) {
|
|
my $cdata = url_params_mixed($cookie);
|
|
|
|
if ($cdata and (ref {} eq ref $cdata)) {
|
|
foreach my $key (keys %{ $defaults }) {
|
|
$defaults->{$key} = $cdata->{$key};
|
|
}
|
|
}
|
|
}
|
|
|
|
# used in the device search sidebar template to set selected items
|
|
foreach my $opt (qw/hgroup lgroup/) {
|
|
my $p = (ref [] eq ref param($opt) ? param($opt)
|
|
: (param($opt) ? [param($opt)] : []));
|
|
$tokens->{"${opt}_lkp"} = { map { $_ => 1 } @$p };
|
|
}
|
|
|
|
return if param('reset')
|
|
or not var('sidebar_key') or (var('sidebar_key') ne 'device_ports');
|
|
|
|
# update cookie from params we just recieved in form submit
|
|
my $uri = URI->new();
|
|
foreach my $key (keys %{ $defaults }) {
|
|
$uri->query_param($key => param($key));
|
|
}
|
|
cookie('nd_ports-form' => $uri->query(), expires => '365 days');
|
|
};
|
|
|
|
get '/device' => require_login sub {
|
|
my $q = param('q');
|
|
my $devices = schema('netdisco')->resultset('Device');
|
|
|
|
# we are passed either dns or ip
|
|
my $dev = $devices->search({
|
|
-or => [
|
|
\[ 'host(me.ip) = ?' => [ bind_value => $q ] ],
|
|
'me.dns' => $q,
|
|
],
|
|
});
|
|
|
|
if ($dev->count == 0) {
|
|
return redirect uri_for('/', {nosuchdevice => 1, device => $q})->path_query;
|
|
}
|
|
|
|
# if passed dns, need to check for duplicates
|
|
# and use only ip for q param, if there are duplicates.
|
|
my $first = $dev->first;
|
|
my $others = ($devices->search({dns => $first->dns})->count() - 1);
|
|
|
|
params->{'tab'} ||= 'details';
|
|
template 'device', {
|
|
is_pseudo => $first->is_pseudo,
|
|
display_name => ($others ? $first->ip : ($first->dns || $first->ip)),
|
|
lgroup_list => [ schema('netdisco')->resultset('Device')->get_distinct_col('location') ],
|
|
hgroup_list => setting('host_group_displaynames'),
|
|
device => params->{'tab'},
|
|
}, { layout => 'main' };
|
|
};
|
|
|
|
true;
|