dff26abc5c
* initial v0 creator * working json api for generic reports * add require login * move report swagger into plugin, and set new default layout of noop * require proper role and also use new util func * start to tidy authn * some work on cleaning up web authn * clean up the authN checks * fix bug * fix the auth for api * fixes to json handling * set swagger sort order * enable most reports for api endpoints * fix doc * add paramters to reports * add missed report * allow api_parameters in reports config * reorganise api * add vlan search * add port search * make sure to enable layout processing * add device search * add v1 to api paths * add Node Search * support api_responses * add device object search; fix spurious ports field in device result class * handle some plugins just returning undef if search fails * errors from api seamlessley * fix error in date range default * more sensible default for prefix * change order of endpoints in swagger-ui * all db row classes can now TO_JSON * add device_port api endpoint * add device ports endpoint * do not expand docs * add swagger ui json tree formatter * add all relations from Device table * add port relations * add nodes retrieve on device or vlan * rename to GetAPIKey * update config for previous commit
105 lines
3.2 KiB
Perl
105 lines
3.2 KiB
Perl
package App::Netdisco::Web::Plugin::Search::Port;
|
|
|
|
use Dancer ':syntax';
|
|
use Dancer::Plugin::DBIC;
|
|
use Dancer::Plugin::Auth::Extensible;
|
|
|
|
use App::Netdisco::Web::Plugin;
|
|
use App::Netdisco::Util::Web 'sql_match';
|
|
|
|
register_search_tab({
|
|
tag => 'port',
|
|
label => 'Port',
|
|
provides_csv => 1,
|
|
api_endpoint => 1,
|
|
api_parameters => [
|
|
q => {
|
|
description => 'Port name or VLAN or MAC address',
|
|
required => 1,
|
|
},
|
|
partial => {
|
|
description => 'Search for a partial match on parameter "q"',
|
|
type => 'boolean',
|
|
default => 'true',
|
|
},
|
|
uplink => {
|
|
description => 'Include uplinks in results',
|
|
type => 'boolean',
|
|
default => 'false',
|
|
},
|
|
ethernet => {
|
|
description => 'Only Ethernet type interfaces in results',
|
|
type => 'boolean',
|
|
default => 'true',
|
|
},
|
|
],
|
|
});
|
|
|
|
# device ports with a description (er, name) matching
|
|
get '/ajax/content/search/port' => require_login sub {
|
|
my $q = param('q');
|
|
send_error( 'Missing query', 400 ) unless $q;
|
|
my $rs;
|
|
|
|
if ( $q =~ m/^\d+$/ ) {
|
|
$rs
|
|
= schema('netdisco')->resultset('DevicePort')
|
|
->columns( [qw/ ip port name up up_admin speed /] )->search({
|
|
"port_vlans.vlan" => $q,
|
|
( param('uplink') ? () : (-or => [
|
|
{-not_bool => "me.is_uplink"},
|
|
{"me.is_uplink" => undef},
|
|
]) ),
|
|
( param('ethernet') ? ("me.type" => 'ethernetCsmacd') : () ),
|
|
},{ '+columns' => [qw/ device.dns device.name port_vlans.vlan /],
|
|
join => [qw/ port_vlans device /]
|
|
}
|
|
)->with_times;
|
|
}
|
|
else {
|
|
my ( $likeval, $likeclause ) = sql_match($q);
|
|
|
|
$rs
|
|
= schema('netdisco')->resultset('DevicePort')
|
|
->columns( [qw/ ip port name up up_admin speed /] )
|
|
->search({
|
|
-and => [
|
|
-or => [
|
|
{ "me.name" => ( param('partial') ? $likeclause : $q ) },
|
|
( length $q == 17
|
|
? { "me.mac" => $q }
|
|
: \[ 'me.mac::text ILIKE ?', $likeval ]
|
|
),
|
|
( param('uplink') ? (
|
|
{ "me.remote_id" => $likeclause },
|
|
{ "me.remote_type" => $likeclause },
|
|
) : () ),
|
|
],
|
|
( param('uplink') ? () : (-or => [
|
|
{-not_bool => "me.is_uplink"},
|
|
{"me.is_uplink" => undef},
|
|
]) ),
|
|
( param('ethernet') ? ("me.type" => 'ethernetCsmacd') : () ),
|
|
]
|
|
},
|
|
{ '+columns' => [qw/ device.dns device.name port_vlans.vlan /],
|
|
join => [qw/ port_vlans device /]
|
|
}
|
|
)->with_times;
|
|
}
|
|
|
|
my @results = $rs->hri->all;
|
|
return unless scalar @results;
|
|
|
|
if ( request->is_ajax ) {
|
|
my $json = to_json( \@results );
|
|
template 'ajax/search/port.tt', { results => $json };
|
|
}
|
|
else {
|
|
header( 'Content-Type' => 'text/comma-separated-values' );
|
|
template 'ajax/search/port_csv.tt', { results => \@results };
|
|
}
|
|
};
|
|
|
|
1;
|