167 lines
4.1 KiB
Perl
Executable File
167 lines
4.1 KiB
Perl
Executable File
#!/usr/bin/env perl
|
|
|
|
use FindBin;
|
|
FindBin::again();
|
|
use Path::Class 'dir';
|
|
|
|
BEGIN {
|
|
# stuff useful locations into @INC
|
|
unshift @INC,
|
|
dir($FindBin::RealBin)->parent->subdir('lib')->stringify,
|
|
dir($FindBin::RealBin, 'lib')->stringify;
|
|
}
|
|
|
|
# for netdisco app config
|
|
use App::Netdisco;
|
|
use Dancer qw/:moose :script/;
|
|
use Dancer::Plugin::DBIC 'schema';
|
|
|
|
=head1 NAME
|
|
|
|
netdisco-do - Run any Netdisco poller job from the command-line.
|
|
|
|
=head1 USAGE
|
|
|
|
~/bin/netdisco-do <action> [-D] [-d <device> [-p <port>] [-e <extra>]]
|
|
|
|
Regardless of Netdisco configuration, debug level logging is enabled if the
|
|
C<-D> flag is given.
|
|
|
|
=head1 DESCRIPTION
|
|
|
|
This program allows you to run any Netdisco poller job from the command-line.
|
|
|
|
Note that some jobs (C<discoverall>, C<macwalk>, C<arpwalk>) simply add
|
|
entries to the Netdisco job queue for other jobs, so won't seem to do much
|
|
when you trigger them.
|
|
|
|
=head1 ACTIONS
|
|
|
|
=head2 discover
|
|
|
|
Run a discover on the device (specified with C<-d>).
|
|
|
|
=head2 macsuck
|
|
|
|
Run a macsuck on the device (specified with C<-d>).
|
|
|
|
=head2 arpnip
|
|
|
|
Run an arpnip on the device (specified with C<-d>).
|
|
|
|
=head2 set_location
|
|
|
|
Set the SNMP location field on the device (specified with C<-d>). Pass the
|
|
location string in the C<-e> extra parameter.
|
|
|
|
=head2 set_contact
|
|
|
|
Set the SNMP contact field on the device (specified with C<-d>). Pass the
|
|
contact name in the C<-e> extra parameter.
|
|
|
|
=head2 set_portname
|
|
|
|
Set the description on a device port. Requires the C<-d> parameter (device),
|
|
C<-p> parameter (port), and C<-e> parameter (description).
|
|
|
|
=head2 set_portcontrol
|
|
|
|
Set the up/down status on a device port. Requires the C<-d> parameter
|
|
(device), C<-p> parameter (port), and C<-e> parameter ("up" or "down").
|
|
|
|
=head2 set_vlan
|
|
|
|
Set the native VLAN on a device port. Requires the C<-d> parameter (device),
|
|
C<-p> parameter (port), and C<-e> parameter (VLAN number).
|
|
|
|
=head2 set_power
|
|
|
|
Set the PoE on/off status on a device port. Requires the C<-d> parameter
|
|
(device), C<-p> parameter (port), and C<-e> parameter ("true" or "false").
|
|
|
|
=cut
|
|
|
|
info "App::Netdisco version $App::Netdisco::VERSION loaded.";
|
|
|
|
use Try::Tiny;
|
|
use Getopt::Long;
|
|
Getopt::Long::Configure ("bundling");
|
|
|
|
my ($device, $port, $extra, $debug);
|
|
my $result = GetOptions(
|
|
'device|d=s' => \$device,
|
|
'port|p=s' => \$port,
|
|
'extra|e=s' => \$extra,
|
|
'debug|D' => \$debug,
|
|
) or exit(1);
|
|
|
|
my $CONFIG = config();
|
|
$CONFIG->{logger} = 'console';
|
|
$CONFIG->{log} = ($debug ? 'debug' : 'info');
|
|
|
|
# reconfigure logging to force console output
|
|
Dancer::Logger->init('console', $CONFIG);
|
|
|
|
# get requested action
|
|
my $action = shift @ARGV;
|
|
|
|
if (!length $action) {
|
|
error 'error: missing action!';
|
|
exit (1);
|
|
}
|
|
|
|
# create worker (placeholder object for the role methods)
|
|
{
|
|
package MyWorker;
|
|
use Moo;
|
|
with 'App::Netdisco::Daemon::Worker::Poller::Device';
|
|
with 'App::Netdisco::Daemon::Worker::Poller::Arpnip';
|
|
with 'App::Netdisco::Daemon::Worker::Poller::Macsuck';
|
|
with 'App::Netdisco::Daemon::Worker::Interactive::DeviceActions';
|
|
with 'App::Netdisco::Daemon::Worker::Interactive::PortActions';
|
|
}
|
|
my $worker = MyWorker->new();
|
|
|
|
# belt and braces check before we go ahead
|
|
if (not $worker->can( $action )) {
|
|
error sprintf 'error: %s is not a valid action', $action;
|
|
exit (1);
|
|
}
|
|
|
|
# static configuration for the in-memory local job queue
|
|
setting('plugins')->{DBIC}->{daemon} = {
|
|
dsn => 'dbi:SQLite:dbname=:memory:',
|
|
options => {
|
|
AutoCommit => 1,
|
|
RaiseError => 1,
|
|
sqlite_use_immediate_transaction => 1,
|
|
},
|
|
schema_class => 'App::Netdisco::Daemon::DB',
|
|
};
|
|
schema('daemon')->deploy;
|
|
|
|
# what job are we asked to do?
|
|
my $job = schema('daemon')->resultset('Admin')->new_result({
|
|
job => 0,
|
|
action => $action,
|
|
device => $device,
|
|
port => $port,
|
|
subaction => $extra,
|
|
});
|
|
|
|
# do job
|
|
my ($status, $log);
|
|
try {
|
|
info sprintf '%s: started at %s', $action, scalar localtime;
|
|
($status, $log) = $worker->$action($job);
|
|
}
|
|
catch {
|
|
$status = 'error';
|
|
$log = "error running job: $_";
|
|
};
|
|
|
|
info sprintf '%s: finished at %s', $action, scalar localtime;
|
|
info sprintf '%s: status %s: %s', $action, $status, $log;
|
|
|
|
exit ($status eq 'done' ? 0 : 1);
|